Alessandro Bonazzi
8c43d5cf2f
Files correlati : cg0.exe cg0700a.msk cg0700b.msk cg3.exe cg4.exe Bug : Commento: Merge 1.0 libraries
143 lines
4.2 KiB
XML
143 lines
4.2 KiB
XML
<?xml version='1.0'?>
|
|
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
|
|
version='1.0'>
|
|
|
|
<!-- ********************************************************************
|
|
$Id$
|
|
********************************************************************
|
|
|
|
This file is part of the XSL DocBook Stylesheet distribution.
|
|
See ../README or http://nwalsh.com/docbook/xsl/ for copyright
|
|
and other information.
|
|
|
|
******************************************************************** -->
|
|
|
|
<xsl:template match="footnote">
|
|
<xsl:variable name="name">
|
|
<xsl:call-template name="object.id"/>
|
|
</xsl:variable>
|
|
<xsl:variable name="href">
|
|
<xsl:text>#ftn.</xsl:text>
|
|
<xsl:call-template name="object.id"/>
|
|
</xsl:variable>
|
|
|
|
<xsl:choose>
|
|
<xsl:when test="ancestor::table|ancestor::informaltable">
|
|
<sup>
|
|
<xsl:text>[</xsl:text>
|
|
<a name="{$name}" href="{$href}">
|
|
<xsl:apply-templates select="." mode="footnote.number"/>
|
|
</a>
|
|
<xsl:text>]</xsl:text>
|
|
</sup>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<sup>
|
|
<xsl:text>[</xsl:text>
|
|
<a name="{$name}" href="{$href}">
|
|
<xsl:apply-templates select="." mode="footnote.number"/>
|
|
</a>
|
|
<xsl:text>]</xsl:text>
|
|
</sup>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="footnoteref">
|
|
<xsl:variable name="targets" select="id(@linkend)"/>
|
|
<xsl:variable name="footnote" select="$targets[1]"/>
|
|
<xsl:variable name="href">
|
|
<xsl:text>#ftn.</xsl:text>
|
|
<xsl:call-template name="object.id">
|
|
<xsl:with-param name="object" select="$footnote"/>
|
|
</xsl:call-template>
|
|
</xsl:variable>
|
|
<sup>
|
|
<xsl:text>[</xsl:text>
|
|
<a href="{$href}">
|
|
<xsl:apply-templates select="$footnote" mode="footnote.number"/>
|
|
</a>
|
|
<xsl:text>]</xsl:text>
|
|
</sup>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="footnote" mode="footnote.number">
|
|
<xsl:choose>
|
|
<xsl:when test="ancestor::table|ancestor::informaltable">
|
|
<xsl:number level="any" from="table|informaltable" format="a"/>
|
|
</xsl:when>
|
|
<xsl:otherwise>
|
|
<xsl:number level="any" format="1"/>
|
|
</xsl:otherwise>
|
|
</xsl:choose>
|
|
</xsl:template>
|
|
|
|
<!-- ==================================================================== -->
|
|
|
|
<xsl:template match="footnote/para[1]">
|
|
<!-- this only works if the first thing in a footnote is a para, -->
|
|
<!-- which is ok, because it usually is. -->
|
|
<xsl:variable name="name">
|
|
<xsl:text>ftn.</xsl:text>
|
|
<xsl:call-template name="object.id">
|
|
<xsl:with-param name="object" select="ancestor::footnote"/>
|
|
</xsl:call-template>
|
|
</xsl:variable>
|
|
<xsl:variable name="href">
|
|
<xsl:text>#</xsl:text>
|
|
<xsl:call-template name="object.id">
|
|
<xsl:with-param name="object" select="ancestor::footnote"/>
|
|
</xsl:call-template>
|
|
</xsl:variable>
|
|
<p>
|
|
<sup>
|
|
<xsl:text>[</xsl:text>
|
|
<a name="{$name}" href="{$href}">
|
|
<xsl:apply-templates select="ancestor::footnote"
|
|
mode="footnote.number"/>
|
|
</a>
|
|
<xsl:text>] </xsl:text>
|
|
</sup>
|
|
<xsl:apply-templates/>
|
|
</p>
|
|
</xsl:template>
|
|
|
|
<!-- ==================================================================== -->
|
|
|
|
<xsl:template name="process.footnotes">
|
|
<xsl:variable name="footnotes" select=".//footnote"/>
|
|
<xsl:variable name="table.footnotes"
|
|
select=".//table//footnote|.//informaltable//footnote"/>
|
|
|
|
<!-- Only bother to do this if there's at least one non-table footnote -->
|
|
<xsl:if test="count($footnotes)>count($table.footnotes)">
|
|
<div class="footnotes">
|
|
<br/>
|
|
<hr width="100" align="left"/>
|
|
<xsl:apply-templates select="$footnotes" mode="process.footnote.mode"/>
|
|
</div>
|
|
</xsl:if>
|
|
</xsl:template>
|
|
|
|
<xsl:template name="process.chunk.footnotes">
|
|
<!-- nop -->
|
|
</xsl:template>
|
|
|
|
<xsl:template match="footnote" mode="process.footnote.mode">
|
|
<div class="{name(.)}">
|
|
<xsl:apply-templates/>
|
|
</div>
|
|
</xsl:template>
|
|
|
|
<xsl:template match="informaltable//footnote|table//footnote"
|
|
mode="process.footnote.mode">
|
|
</xsl:template>
|
|
|
|
<xsl:template match="footnote" mode="table.footnote.mode">
|
|
<div class="{name(.)}">
|
|
<xsl:apply-templates/>
|
|
</div>
|
|
</xsl:template>
|
|
|
|
</xsl:stylesheet>
|